¹By "tricks," I mean various automation functions that allow me to centralize and automate the generation of certain blocks of page HTML - particularly navigation, headers, footers, and (to a limited extent) the presentation of data. I originally developed many of these functions back in 1999 and 2000 using the VBScript language. Most of these functions began their life as specific solutions to a particular problem. Over several code-generations, I made the functions increasingly generic to accommodate their many possible uses. I would take a function that started out as single-purpose one-way data translator and make it so it could work both ways. Then I'd add a provision for it to accept its data as a parameter in the form of a delimited text string. It would go from looking like this (Summer, 1999):

function MakeKosher(strIn)
	strIn=replace(strIn, "^", "")
	strIn=replace(strIn, "|", "")
	strIn=replace(strIn, " ", "")
	strIn=replace(strIn, chr(13), "")
	strIn=replace(strIn, chr(10), "")
	select case lcase(strIn)
		case "red"
		MakeKosher="ff0000"
		case "green"
		MakeKosher="00cc00"
		case "blue"
		MakeKosher="0000ff"
		case "yellow"
		MakeKosher="ffff00"
		case "grey"
		MakeKosher="999999"
		case "orange"
		MakeKosher="ff9900"
		case "white"
		MakeKosher="ffffff"
		case "black"
		MakeKosher="000000"
		case "brown"
		MakeKosher="996600"
		case "navy"
		MakeKosher="000099"
		case "ruby"
		MakeKosher="990000"
		case "forest"
		MakeKosher="009900"
		case "maroon"
		MakeKosher="660000"
		case "spinach"
		MakeKosher="006600"
		case "pool"
		MakeKosher="000066"
		case else
		MakeKosher=lcase(strIn)
		if len(MakeKosher)>6 then MakeKosher=left(MakeKosher, 6)
	end select
end function

function FromKosher(strIn)
	select case lcase(strIn)
		case "ff0000"
		FromKosher="red"
		case "00cc00"
		FromKosher="green"
		case "0000ff"
		FromKosher="blue"
		case "ffff00"
		FromKosher="yellow"
		case "999999"
		FromKosher="grey"
		case "ff9900"
		FromKosher="orange"
		case "ffffff"
		FromKosher="white"
		case "996600"
		FromKosher="brown"
		case "000000"
		FromKosher="black"
		case "009900"
		FromKosher="forest"
		case "990000"
		FromKosher="ruby"
		case "660000"
		FromKosher="maroon"
		case "006600"
		FromKosher="spinach"
		case "000066"
		FromKosher="pool"
		case "000099"
		FromKosher="navy"
		case else
		FromKosher=strIn
	end select
end function

To this (April, 2000):

function ColorTrans(strIn, intTypeIn, intTypeOut)
	'the wisdom of color translation
	'where intTypes 0=colorname 1=colorvalue
	'this basically does a tablescan of the data in strTranslates looking for one side of the value pair and
	'returning the other
	'Gus Mueller, April 2000
	dim strTranslate, arrTranslate, i, strOut, bwlDone, arrThis
	strIn=cstr(strIn)
	strTranslate="red|ff0000-green|00cc00-blue|0000ff-yellow|ffff00-grey|999999-orange|ff9900-white|ffffff-black|000000-brown|996600-navy|000099-ruby|990000-forest|009900-maroon|660000-spinach|006600-pool|000066-pink|ff9999"
arrTranslate=split(strTranslate, "-")
	bwlDone=false
	i=0
	do until i > ubound(arrTranslate) or bwlDone=true
		arrThis=split(arrTranslate(i), "|")
		if lcase(arrThis(intTypeIn))=lcase(strIn) then
			strOut=arrThis(intTypeOut)
			bwlDone=true
		end if
		i=i+1
	loop
	if strOut="" then
		strOut="999999"
		if len(strIn)=6 then
			strOut=colorsafe(strIn)
		end if
	end if
	ColorTrans=strOut
end function

To this (June, 2000):

function Data(strIn, intTypeIn, intTypeOut, strTranslate)
	'ALLOWS us to read data in double-delimited strings of the form a|b|.|.|.-c|d|.|.|.-.-.-.
	'Gus Mueller, April 2000
	dim arrTranslate, i, strOut, bwlDone, arrThis
	strIn=cstr(strIn)
	if strTranslate<>"" then
		if instr(strTranslate, "-")>0 then
			arrTranslate=split(strTranslate, "-")
		else
			arrTranslate=split(strTranslate, "|")
		end if
	end if
	bwlDone=false
	i=0
	do until i > ubound(arrTranslate) or bwlDone=true
		arrThis=split(arrTranslate(i), "|")
		if intTypeOut=-1 then
			strOut=strIn
		else
			if intTypeIn<=ubound(arrThis) and intTypeOut<=ubound(arrThis) then
				if intTypeIn=-1 then
					if cstr(strIn)=cstr(i) then
						if ubound(arrThis)<1 then
							strOut=arrTranslate(i)
						else
							strOut=arrThis(intTypeOut)
						end if
						bwlDone=true
					end if
				elseif lcase(arrThis(intTypeIn))=lcase(strIn) then
					strOut=arrThis(intTypeOut)
					bwlDone=true
				end if
			end if
		end if
		i=i+1
	loop
	if strOut="" then
		strOut=""
	end if
	Data=strOut
end function

For linking purposes this article's URL is:
http://asecular.com/blog.php?041018